buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:0.12.+'
    }
}

apply plugin: 'com.android.application'

repositories {
    mavenCentral()
}

android {
    lintOptions {
        lintConfig file("../lint.xml")
    }

    compileSdkVersion 19
    buildToolsVersion "20"

    defaultConfig {
        minSdkVersion 7
        targetSdkVersion 19
    }

    signingConfigs {
        release
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }

    buildTypes {
        release {
            signingConfig signingConfigs.release
        }
    }

    if (project.hasProperty('keyAlias') &&
            project.hasProperty('storeFile') &&
            project.hasProperty('storePassword') &&
            project.hasProperty('keyPassword')) {
        android.signingConfigs.release.keyAlias = keyAlias
        android.signingConfigs.release.storeFile = file(storeFile)
        android.signingConfigs.release.storePassword = storePassword
        android.signingConfigs.release.keyPassword = keyPassword
    } else {
        buildTypes.release.signingConfig = null
    }
}

android.applicationVariants.all { variant ->
    variant.mergeResources.doLast {
        if (project.hasProperty('gapiKey')) {
            File values = file("${buildDir}/intermediates/res/${variant.dirName}/values/values.xml")
            values.write(
                    values.getText('UTF-8').replaceAll(/<string name="gapi_key">.*<\/string>/, "<string name=\"gapi_key\">${project.property('gapiKey')}</string>"),
                    'UTF-8')
        }
    }
}

dependencies {
    provided group: 'com.squareup.dagger', name: 'dagger-compiler', version: '1.2.1'

    compile group: 'com.android.support', name: 'appcompat-v7', version: '19.1.+'

    compile 'net.simonvt.menudrawer:menudrawer:3.0.4@aar'

    compile project(":api")

    compile group: 'com.rubiconproject.oss', name: 'jchronic', version: '0.2.6', transitive: false
    compile group: 'org.scala-saddle', name: 'google-rfc-2445', version: '20110304', transitive: false

    compile group: 'com.google.apis', name: 'google-api-services-tasks', version: 'v1-rev33-1.18.0-rc'
    compile group: 'com.google.api-client', name: 'google-api-client-android', version: '1.18.0-rc'
    compile group: 'com.google.http-client', name: 'google-http-client-android', version: '1.18.0-rc'
    compile group: 'com.google.http-client', name: 'google-http-client-gson', version: '1.18.0-rc'

    androidTestCompile group: 'org.mockito', name: 'mockito-core', version: '1.9.5', transitive: false
    androidTestCompile group: 'com.google.dexmaker', name: 'dexmaker', version: '1.1'
    androidTestCompile group: 'com.google.dexmaker', name: 'dexmaker-mockito', version: '1.1'
}