tailscale-android/android/build.gradle

buildscript {
    ext.kotlin_version = "1.9.22"
    ext.kotlin_compose_version = "1.5.10"

    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath "com.android.tools.build:gradle:8.1.4"
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath "org.jetbrains.kotlin:kotlin-serialization:$kotlin_version"
    }
}

repositories {
    google()
    mavenCentral()
    flatDir {
        dirs 'libs'
    }
}

apply plugin: 'kotlin-android'
apply plugin: 'com.android.application'
apply plugin: 'org.jetbrains.kotlin.plugin.serialization'

android {
    ndkVersion "23.1.7779620"
    compileSdkVersion 34
    defaultConfig {
        minSdkVersion 26
        targetSdkVersion 34
        versionCode 198
        versionName "1.59.53-t0f042b981-g1017015de26"
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }
    buildFeatures {
        compose true
    }
    composeOptions {
        kotlinCompilerExtensionVersion = "$kotlin_compose_version"
    }
    flavorDimensions "version"
    productFlavors {
        fdroid {
            // The fdroid flavor contains only free dependencies and is suitable
            // for the F-Droid app store.
        }
        play {
            // The play flavor contains all features and is for the Play Store.
        }
    }
    namespace 'com.tailscale.ipn'
}

dependencies {
    // Android dependencies.
    implementation "androidx.core:core:1.12.0"
    implementation 'androidx.core:core-ktx:1.12.0'
    implementation "androidx.browser:browser:1.8.0"
    implementation "androidx.security:security-crypto:1.1.0-alpha06"
    implementation "androidx.work:work-runtime:2.9.0"

    // Kotlin dependencies.
    implementation "org.jetbrains.kotlinx:kotlinx-serialization-json:1.6.3"
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:1.8.0"
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-android:1.8.0"
    implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"

    // Compose dependencies.
    def composeBom = platform('androidx.compose:compose-bom:2023.06.01')
    implementation composeBom
    androidTestImplementation composeBom
    implementation 'androidx.compose.material3:material3:1.2.1'
    implementation 'androidx.compose.material:material-icons-core:1.6.3'
    implementation "androidx.compose.ui:ui:1.6.3"
    implementation "androidx.compose.ui:ui-tooling:1.6.3"
    implementation 'androidx.lifecycle:lifecycle-runtime-ktx:2.7.0'
    implementation 'androidx.lifecycle:lifecycle-viewmodel-ktx:2.7.0'
    implementation 'androidx.activity:activity-compose:1.8.2'

    // Navigation dependencies.
    def nav_version = "2.7.7"
    implementation "androidx.navigation:navigation-fragment:$nav_version"
    implementation "androidx.navigation:navigation-ui:$nav_version"
    implementation "androidx.navigation:navigation-fragment-ktx:$nav_version"
    implementation "androidx.navigation:navigation-ui-ktx:$nav_version"
    implementation "androidx.navigation:navigation-dynamic-features-fragment:$nav_version"
    implementation "androidx.navigation:navigation-compose:$nav_version"

    // Supporting libraries.
    implementation("io.coil-kt:coil-compose:2.6.0")

    // Tailscale dependencies.
    implementation ':ipn@aar'

    // Tests
    testImplementation "junit:junit:4.12"
    androidTestImplementation "androidx.navigation:navigation-testing:$nav_version"

    // Non-free dependencies.
    playImplementation 'com.google.android.gms:play-services-auth:20.7.0'
}

def ndkPath = project.hasProperty('ndkPath') ? project.property('ndkPath') : System.getenv('ANDROID_SDK_ROOT')

task checkNDK {	
    doFirst {
		if (ndkPath == null) {
			throw new GradleException('NDK path not found. Please define ndkPath in local.properties or ANDROID_SDK_HOME environment variable.')
		}
	}
}

task buildGoLibArm64(type: Exec) {
	inputs.dir '../pkg/tailscale'
	outputs.file 'src/main/jniLibs/arm64-v8a/libtailscale.so'
    environment "CC", "$ndkPath/ndk-bundle/toolchains/llvm/prebuilt/darwin-x86_64/bin/aarch64-linux-android30-clang"
    commandLine 'sh', '-c', "GOOS=android GOARCH=arm64 CGO_ENABLED=1 go build -buildmode=c-shared -ldflags=-w -o src/main/jniLibs/arm64-v8a/libtailscale.so ../pkg/tailscale"
}

task buildGoLibArmeabi(type: Exec) {
	inputs.dir '../pkg/tailscale'
	outputs.file 'src/main/jniLibs/armeabi-v7a/libtailscale.so'
    environment "CC", "$ndkPath/ndk-bundle/toolchains/llvm/prebuilt/darwin-x86_64/bin/armv7a-linux-androideabi30-clang"
    commandLine 'sh', '-c', "GOOS=android GOARCH=arm CGO_ENABLED=1 go build -buildmode=c-shared -ldflags=-w -o src/main/jniLibs/armeabi-v7a/libtailscale.so ../pkg/tailscale"
}

task buildGoLibX86(type: Exec) {
	inputs.dir '../pkg/tailscale'
	outputs.file 'src/main/jniLibs/x86/libtailscale.so'
    environment "CC", "$ndkPath/ndk-bundle/toolchains/llvm/prebuilt/darwin-x86_64/bin/i686-linux-android30-clang"
    commandLine 'sh', '-c', "GOOS=android GOARCH=386 CGO_ENABLED=1 go build -buildmode=c-shared -ldflags=-w -o src/main/jniLibs/x86/libtailscale.so ../pkg/tailscale"
}

task buildGoLibX86_64(type: Exec) {
	inputs.dir '../pkg/tailscale'
	outputs.file 'src/main/jniLibs/x86_64/libtailscale.so'
    environment "CC", "$ndkPath/ndk-bundle/toolchains/llvm/prebuilt/darwin-x86_64/bin/x86_64-linux-android30-clang"
    commandLine 'sh', '-c', "GOOS=android GOARCH=amd64 CGO_ENABLED=1 go build -buildmode=c-shared -ldflags=-w -o src/main/jniLibs/x86_64/libtailscale.so ../pkg/tailscale"
}

task buildAllGoLibs {
    dependsOn checkNDK, buildGoLibArm64, buildGoLibArmeabi, buildGoLibX86, buildGoLibX86_64
}

assemble.dependsOn buildAllGoLibs

task cleanGoLibs(type: Delete) {
    delete 'src/main/jniLibs/arm64-v8a/libtailscale.so',
           'src/main/jniLibs/armeabi-v7a/libtailscale.so',
           'src/main/jniLibs/x86/libtailscale.so',
           'src/main/jniLibs/x86_64/libtailscale.so'
}

clean.dependsOn cleanGoLibs

tasks.whenTaskAdded { task ->
    if (task.name.startsWith('merge') && task.name.endsWith('JniLibFolders')) {
        task.mustRunAfter buildAllGoLibs
    }
}